#REM   Li-Ion Battery Management System Slave (DIGITAL PCB / On/Off Charger Control) 
By Peter Perkins. Picaxe 08M - PIC12F683 - 211208 - www.150mpg.co.uk - V.01 Beta.
**************************** General Information *********************************

The BMS modules carry no warranty or guarantee of any kind! They are used at
your own risk, and I make no claims as to their suitability for a particular
function. Prospective users must evaluate the system before using it, and no
liability will be entertained by myself in any shape or form whatsoever.
The modules and software have been produced at low cost for the benefit of
the EV & electronic community. The software is available free via the internet.
Users may modify or adapt the system as they see fit. If you are not fully
competent to work on potentially lethal battery systems and high voltages,
then do not experiment with or use this system. Be aware that vehicle
modifications can lead to invalidated insurance and warranty issues. You the
end user remain fully liable for any modifications made to your vehicle.   

************************* Slave Picaxe 08M Pinouts *******************************
                                    				
                                    Top					
                                   _____
(+ Cell Supply)             +Ve -1|  ^  |8- -Ve                    (- Cell Supply)
(Program In)                Rxd -2|  0  |7- Output 0             (Bypass Load Out)
(Low V Opto Out)       Output 4 -3|  8  |6- Input 1             (RefAdc In 1.235V) 
(Slave Data Bus In)     Input 3 -4|  M  |5- Output 2             (High V Opto Out)
                                   ----- 

******************** Analogue Slave Module Specifications ************************

Supply/Cell Voltage 1.75 - 5.00V DC (Pic limits)
Average Supply Current at 3.35v <1ma
Voltage Ref LM 385 1.235V accuracy 1%
Supply/Cell Voltage sensing accuracy +/- 20mv
Maximum balancing/bypass current with 15R resistor 333ma at 5.00V
CPU Speed 31khz - 8mhz with internal resonator (Lower speed used for power saving) 
Permitted Working Cell Voltage Range 1.75 - 4.30V
Note Slave Opto's are Sink driven therefore (Pic Output Low = Opto On, High = Opto Off)

***************************** Slave Clock Speeds *********************************
*********************** Reducing CPU Speed Saves Power ***************************
******** Use the slowest speed setting that gives acceptable performance *********

%00000000 = 31 kHz 19bps
%00010000 = 125 kHz 75bps
%00100000 = 250 kHz 150bps
%00110000 = 500 kHz 300bps
%01000000 = 1 MHz 600bps
%01010000 = 2 MHz 1200bps
%01100000 = 4 MHz 2400bps
%01110000 = 8 MHz 4800bps

Example = poke $8F,%01100000 'Set clock to 4 MHz

**********************************************************************************
********************** Program Size 80 out of 256 Bytes **************************
**********************************************************************************

***************************** Simulation Notes ********************************

Use a generic adc input of 650 to simulate a cell voltage of 1.92V
Use a generic adc input of 400 to simulate a cell voltage of 3.16V 
Use a generic adc input of 300 to simulate a cell voltage of 4.20V 

#ENDREM

#picaxe 08m					;Set Picaxe editor to 08M mode

`Variables Constants and I/O definitions

`Variables 16bit

symbol CellV	   = w0		;w0 (b0,b1) = Corrected Cell voltage (16bit value)
symbol RefADC      = w1		;w1 (b2,b3) = Raw Adc input data variable range 0-1023 10bit
symbol CellA       = w2		;w2 (b4,b5) = Cell average voltage last 10 measurements
symbol PreV        = w3		;w3 (b6,b7) = Previous cell voltage, preserves Cell V from last loop

`Variables 8bit

symbol CountB      = b13	;b13 = General 0-255 byte ADC loop counter variable

`Constants

symbol RefVADC     = 63200      ;Fixed Ref Voltage Calibration LM385 1.235v * 1023 * 100 / 2 = 63200

symbol MaxVOptoOn    = 375	;Maximum Cell Voltage Opto On  > 3.75V (High Cell V Alarm On) 
symbol MaxVOptoOff   = 370	;Maximum Cell Voltage Opto Off < 3.70V (High Cell V Alarm Off) 

symbol LoadOn        = 360	;Balancing load/bypass cut in Voltage  > 3.60V (Load cut in point)
symbol LoadOff       = 355	;Balancing load/bypass cut out Voltage < 3.55V (Load cut out point)

symbol MinVOptoOn    = 240      ;Minimum Cell Voltage Opto On  < 2.40V (Low Cell V Alarm On ) 
symbol MinVOptoOff   = 250      ;Minimum Cell Voltage Opto Off > 2.50V (Low Cell V Alarm Off) 

`Pins used for I/O and designations

`*** Digital high/low Outputs ***

symbol Load          = 0	;2W 15R Transistor driven load/bypass resistor on Output 0
symbol HighOpto      = 2    	;HighOpto on Output 2
symbol LowOpto       = 4	;LowOpto on Output 4

`*** Analogue ADC Inputs ***

symbol RefInput      = 1	;LM385 1.235V RefAdc on Input 1

`**********************************************************************************
`**********************************************************************************

Start:				;Main program start

	disablebod		;Disable Pic Chip Brown Out Detection to function at lower supply V

`**********************************************************************************

`Note Slave Opto's are Sink driven, therefore (Pic Output Low = Opto On, High = Opto Off)

Main:					;Main program loop label
	
	CellA = 0 				;Set Cell Average word variable to 0 (Zero)
	
	for CountB = 1 to 10			;10x ADC Oversampling loop counter
	readadc10 RefInput, RefADC		;Measure ADC voltage reference
	CellA = CellA + RefADC			;Add latest ADC reading to running total
	next CountB				;Repeat loop until 10 ADC readings obtained
	
	CellA = CellA / 10			;Calculate average ADC reading for last 10 readings

	CellV = RefVADC / CellA * 2 		;Calculate Cell Voltage from the average ADC LM385 VRef 1.235v reading
	
	if CellV > MaxVOptoOn then		;If Cell V > MaxVOptoOn then
	low HighOpto				;Turn on HighOpto (Warning/Charger/Controller/Regen Cutback) {Stop Charger}
	endif	

	if CellV < MaxVOptoOff then		;If Cell V < MaxVOptoOff then
	high HighOpto				;Turn off HighOpto (Warning/Charger/Controller/Regen Cutback) {Start Charger}
	endif	
	
	if CellV > LoadOn then			;If Cell V > LoadOn then
	high Load				;Turn on load (and load indicator led If fitted)
	endif
	
	if CellV < LoadOff then			;If Cell V < LoadOff then
	low Load				;Turn off load (and load indicator led if fitted)
	endif	
	
	if CellV < MinVOptoOn or pin3 = 1 then	;If Cell V < MinVOptoOn then
	low LowOpto				;Turn on LowOpto  (Low Cell V Alarm On ) & led if fitted)
	endif
	
	if CellV > MinVOptoOff and pin3 = 0 then	;If Cell V > MinVOptoOff then
	high LowOpto				;Turn off LowOpto (Low Cell V Alarm Off) & led if fitted)
	endif

	goto Main			;Goto program main loop